// File di specifica JavaCup per un compilatore di espressioni
/* Data un'espressione ne costruisce il parse tree */

import java_cup.runtime.*;

class Parser;    //nome da attribuire al parser (classe generata)
                 //la classe per i token avra' lo stesso nome seguito da Sym (ParserSym)


action code {:
  SymbolTable symbolTable = new SymbolTable();
:}


/* Simboli terminali (token restituiti dallo scanner). */
terminal           PIU, MENO, PER, DIVISO;
terminal           UNARIO, TONDA_APERTA, TONDA_CHIUSA;
terminal Integer   NUMERO;
terminal String    IDENT;


/* Non terminali */
non terminal Expr  expr;
non terminal ExprConTab expr1;

/* Precedenze e associativita' */
precedence left PIU, MENO;
precedence left PER, DIVISO;
precedence nonassoc UNARIO;


/* Simbolo iniziale */
start with expr1;

/* Produzioni */
expr1     ::= expr:e
              {: RESULT = new ExprConTab(e, symbolTable); :}
	      ;

expr      ::= expr:e1 PIU expr:e2    
	      {: RESULT = new PiuExpr(e1, e2); :} 
	      | 
              expr:e1 MENO expr:e2    
              {: RESULT = new MenoExpr(e1, e2); :} 
	      | 
              expr:e1 PER expr:e2 
	      {: RESULT = new PerExpr(e1, e2); :} 
	      | 
              expr:e1 DIVISO expr:e2 
	      {: RESULT = new DivisoExpr(e1, e2); :} 
	      | 
              NUMERO:n                 
	      {: RESULT = new NumExpr(n); :} 
	      |
              IDENT:id              
              {: Descrittore d = symbolTable.trovaEAggiungi(id);
                 RESULT = new IdExpr(d); :} 
              | 
              MENO expr:e             
	      {: RESULT = new UnMenoExpr(e); :} 
	      %prec UNARIO
	      | 
              PIU expr:e             
	      {: RESULT = new UnPiuExpr(e); :} 
	      %prec UNARIO
	      | 
              TONDA_APERTA expr:e TONDA_CHIUSA
	      {: RESULT = e; :} 
	      ;